unit Unit2;

interface
uses Controls,Graphics,Classes,Types;

type
 TLED = class(TGraphicControl)
 private
   FOnColor: TColor;
   FOffColor: TColor;
   FLedOn: Boolean;

   FOnChange: TNotifyEvent;

   procedure SetLedOn(Value: Boolean);
   procedure SetOnColor(Value: TColor);
   procedure SetOffColor(Value: TColor);

   procedure DrawLedEllipse;

 protected
   procedure Paint; override;
   procedure DoChange; virtual;

 public
   constructor Create(AOwner: TComponent); override;

 published
   property OnColor: TColor read FOnColor write SetOnColor;
   property OffColor: TColor read FOffColor write SetOffColor;
   property LedOn: Boolean read FLedOn write SetLedOn;

   property Visible;

   property OnChange: TNotifyEvent read FOnChange write FOnChange;
 end;

implementation

{ TLED }

constructor TLED.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FOnColor := clLime;
  FOffColor := clRed;
  FLedOn := false;

  width := 24;
  height := 24;

end;

procedure TLED.DoChange;
begin
  if Assigned(FOnChange) then FOnChange(self);

end;

procedure TLED.DrawLedEllipse;
var R: TRect;
    off: Integer;
begin
  R := ClientRect;
  if Height>Width then
    off := Width div 5
  else
    off := Height div 5;


  with Canvas do
  begin
    Pen.Color :=Canvas.Brush.Color;
    Ellipse(R.Left,R.Top,R.Right,R.Bottom);

    //3D effect
    Pen.Color := clWhite;
    Brush.Color := clWhite;
    Chord(R.Left+off, R.Top+off,
          R.Right-off, R.Bottom-off,
          R.Right div 2, R.Top+off,
          R.Left+off, R.Bottom div 2); 
  end;

end;

procedure TLED.Paint;
begin
  inherited;
  if  FLedOn then
    Canvas.Brush.Color := FOnColor
  else
    Canvas.Brush.Color := FOffColor;

  DrawLedEllipse;

end;

procedure TLED.SetLedOn(Value: Boolean);
begin
  if Value<>FLedOn then
  begin
    FLedOn := Value;
    Refresh;
    DoChange;
  end;
end;

procedure TLED.SetOffColor(Value: TColor);
begin
  if FOffColor<>Value then
  begin
    FOffColor := Value;
    Refresh;
  end;

end;

procedure TLED.SetOnColor(Value: TColor);
begin
  if FOnColor<>Value then
  begin
    FOnColor := Value;
    Refresh;
  end
end;

end.

procedure TForm1.FormCreate(Sender: TObject);
begin
  LED :=TLED.Create(Self);
  LED.Parent :=Self;
  
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  LED.LedOn := not LED.LedOn; 
end;